Footers

    site "Minimal footer"
  colors ink #141414, paper #FAFAF7
  fonts "Satoshi"
  style background paper, color ink

page "/"
  spacer 40
  footer
    text "© 2026 Northwind"
    row gap 24
      link "Privacy" "#", plain
      link "Terms" "#", plain
      link "Twitter ↗" "#", plain
    ```

    site "Wordmark footer"
  colors night #0B0B0C, lime #C6FF4D
  fonts "Satoshi", "Anton"
  style background night, color white

style links-col
  gap 6
  link color #FFFFFFB3, plain

style wordmark
  font "titles", size 240, uppercase, line-height 0.8, color lime, center, tracking -4

page "/"
  section end, padding 48 40 0
    row gap 64
      column links-col
        text "Studio", weight 700
        link "Work" "#"
        link "About" "#"
        link "Jobs" "#"
      column links-col
        text "Social", weight 700
        link "Instagram ↗" "#"
        link "LinkedIn ↗" "#"
      column links-col, margin 0 0 0 auto
        text "Say hi", weight 700
        link "hello@volt.studio" "#"
    title "Volt®", wordmark
    ```

    site "Columns footer"
  colors night #0F1115, slate #9AA3B2, blue #4D7CFF
  fonts "Satoshi"
  style background night, color white

let cols = [
  { t: "Product", l: ["Features", "Pricing", "Changelog", "Status"] },
  { t: "Company", l: ["About", "Careers", "Press", "Contact"] },
  { t: "Resources", l: ["Docs", "Guides", "Community", "Security"] }
]

style col
  gap 10
  link color slate, plain, size 15

page "/"
  section end, padding 56 48
    grid columns 1.5 1 1 1, gap 32
      tablet columns 2
      column gap 14
        text "◆ Prism", size 22, weight 800
        text "Analytics that respect people.", color slate
      for c in cols
        column col
          text c.t, weight 700
          for x in c.l
            link x "#"
    row border-top 1 #FFFFFF14, padding 24 0 0 0
      text "© 2026 Prism SA, Geneva", color slate, size 14
      text "Made with Kaury", color slate, size 14, margin 0 0 0 auto
    ```

    site "Brutalist footer"
  colors acid #D7FF3A, ink #111111, pink #FF4FA3
  fonts "Space Grotesk", "Anton"
  style background acid, color ink

style box-in
  border 3 ink, background white, padding 28, gap 16, shadow hard ink, radius 0

page "/"
  section end, padding 40 48
    grid columns 1.2 1, gap 32
      tablet columns 1
      title "Get the\nzine →", font "titles", size 110, uppercase, line-height 0.85
      column box-in
        text "One email a month. Ideas, not ads.", weight 700
        form -> joined = true
          field email "you@mail.com", type email, required
          button "Subscribe", background ink, color acid, radius 0, shadow none, uppercase
        if joined
          text "You are in. ✳", color #C2367A, weight 800
    row border-top 3 ink, padding 18 0 0 0
      text "KILN—STUDIO © 2026", font "mono"
      text "BERLIN / ONLINE", font "mono", margin 0 0 0 auto
    ```